# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI="6"

[[ "${PV}" = "9999" ]] && inherit git-r3

PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="threads(+)"
inherit python-any-r1 waf-utils

DESCRIPTION="A simple Linux Guitar Amplifier for jack with one input and two outputs"
HOMEPAGE="http://guitarix.sourceforge.net/"

RESTRICT="mirror"
if [ "${PV}" = "9999" ]; then
	EGIT_REPO_URI="git://git.code.sf.net/p/guitarix/git/"
	S="${S}/trunk"
	KEYWORDS=""
else
	SRC_URI="mirror://sourceforge/guitarix/guitarix/${P}.tar.xz"
	S="${WORKDIR}/guitarix-${PV}"
	KEYWORDS="~amd64 ~x86"
fi

SLOT="0"
LICENSE="GPL-2"

IUSE="avahi debug nls"

RDEPEND="dev-cpp/eigen:3
	dev-cpp/glibmm:2
	dev-cpp/gtkmm:2.4
	dev-libs/boost
	dev-libs/glib
	media-libs/liblrdf
	media-libs/libsndfile
	media-libs/lilv:0
	virtual/jack
	media-sound/jack-audio-connection-kit
	media-sound/lame
	sci-libs/fftw:3.0
	x11-libs/gtk+:2
	media-fonts/roboto
	avahi? ( net-dns/avahi )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	nls? ( dev-util/intltool )"
RDEPEND="${RDEPEND}
	media-sound/meterbridge"

DOCS=( changelog README )

src_unpack() {
	[[ "${PV}" = "9999" ]] && git-r3_src_unpack || default
}

src_configure() {
	local mywafconfargs=(
		--nocache
		--shared-lib
		--lib-dev
		--no-ldconfig
		--no-desktop-update
		$(use_enable nls)
		$(usex avahi "" --no-avahi)
		$(usex debug --debug "")
	)

	waf-utils_src_configure ${mywafconfargs[@]}
}